bzoj3211，bzoj3038

线段树的裸题；

但是操作很奇怪，开方是不能lazy tag的

看来只能暴力修改了

但注意，开放开到1的时候就不用开，立一个flag就可以了

这可以大大的优化；

其实我是来复习线段树的

var tree:array[0..400010] of int64;
    lazy:array[0..400010] of boolean;
    a:array[0..100010] of int64;
    n,m,ch,p,q,l,r,i:longint;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure update(i:longint);
  begin
    tree[i]:=tree[i*2]+tree[i*2+1];
    lazy[i]:=lazy[i*2] and lazy[i*2+1];
  end;

procedure build(i,l,r:longint);
  var m:longint;
  begin
    if l=r then
    begin
      tree[i]:=a[l];
      lazy[i]:=false;
    end
    else begin
      m:=(l+r) shr 1;
      build(i*2,l,m);
      build(i*2+1,m+1,r);
      update(i);
    end;
  end;

procedure work(i,l,r:longint);
  var m:longint;
  begin
    if l=r then
    begin
      tree[i]:=trunc(sqrt(tree[i]));
      if tree[i]=1 then lazy[i]:=true;
    end
    else begin
      m:=(l+r) shr 1;
      if (p<=m) and not lazy[i*2] then work(i*2,l,m);
      if (q>m) and not lazy[i*2+1] then work(i*2+1,m+1,r);
      update(i);
    end;
  end;

function ask(i,l,r:longint):int64;
  var m:longint;
  begin
    if (p<=l) and (q>=r) then exit(tree[i])
    else begin
      m:=(l+r) shr 1;
      ask:=0;
      if p<=m then ask:=ask+ask(i*2,l,m);
      if q>m then ask:=ask+ask(i*2+1,m+1,r);
    end;
  end;

begin
  readln(n);
  for i:=1 to n do
    read(a[i]);
  build(1,1,n);
  readln(m);
  for i:=1 to m do
  begin
    readln(ch,p,q);
    if p>q then swap(p,q);
    if ch=0 then
      work(1,1,n)
    else if ch=1 then
      writeln(ask(1,1,n));
  end;
end.