poj2186

奶牛来奶牛去的，用图论说白了就是

找统计有向图有多少个点，其他每个点都能到达这个点

考虑到一个特性，在一个强联通分量中，如果一个点能被其他所有点到达，那必定这个分量中其他点也一定符合要求

于是我们考虑用tarjan缩点（将一个强连通分量看做一个点）

缩点后，如果存在只有一个出度为0的点（必定存在，否则就被tarjan缩成1个点）

那么显然答案就是这个点的规模

如果有两个以上的出度为0的点，那么必然的这两个点必不能相互到达，答案就是不能存在

问题得解

type link=^node;
     node=record
       data:longint;
       next:link;
     end;
var w:array[0..10010] of link;
    dfn,low,fa,st,size,cd:array[0..10010] of longint;
    f,v:array[0..10010] of boolean;
    s,sum,i,j,y,x,n,m,t,h:longint;
    p:link;
procedure add(x,y:longint);
  var p:link;
  begin
    new(p);
    p^.data:=y;
    p^.next:=w[x];
    w[x]:=p;
  end;

procedure tarjan(x:longint);
  var y:longint;
      p:link;
  begin
    inc(t);
    inc(h);
    f[x]:=true;
    v[x]:=true;
    st[t]:=x;
    dfn[x]:=h;
    low[x]:=h;
    p:=w[x];
    while p<>nil do
    begin
      y:=p^.data;
      if not v[y] then
      begin
        tarjan(y);
        low[x]:=min(low[x],low[y]);
      end
      else if f[y] then low[x]:=min(low[x],low[y]);
      p:=p^.next;
    end;
    if low[x]=dfn[x] then   //找到一个强连通分量
    begin
      inc(s);
      while st[t+1]<>x do
      begin
        y:=st[t];
        f[y]:=false;
        fa[y]:=s;           //缩点，记录规模
        inc(size[s]);
        dec(t);
      end;
    end;
  end;

begin
  readln(n,m);
  for i:=1 to m do
  begin
    readln(x,y);
    add(x,y);
  end;
  s:=0;
  for i:=1 to n do
    if not v[i] then tarjan(i);
  fillchar(cd,sizeof(cd),0);
  for i:=1 to n do
  begin
    p:=w[i];
    while p<>nil do
    begin
      y:=p^.data;
      if fa[y]<>fa[i] then inc(cd[fa[i]]);  //统计缩点后的出度
      p:=p^.next;
    end;
  end;
  sum:=0;
  y:=0;
  for i:=1 to s do
    if cd[i]=0 then
    begin
      inc(sum);
      y:=i;
      if sum>1 then break;
    end;
  if (sum>1) or (sum=0) then writeln(0)
  else writeln(size[y]);
end.