bzoj2797

对和排序，显然最小是a1+a2,次小a1+a3 然后穷举哪里是a2+a3 这样a1,a2,a3就求出来了

注意a2+a3只可能是前n+1项中的一个，所以穷举这步是O(n)的

接下来我们把已经确定的数的和找到并标记，那么下一个未标记的和就是a1+新的数，然后依次递推下去即可

var v:array[0..50010] of boolean;
    a:array[0..50010] of longint;
    b:array[0..310] of longint;
    ans:array[0..10010,0..310] of longint;
    i,j,n,m,t:longint;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure sort(l,r:longint);
  var i,j,x:longint;
  begin
    i:=l;
    j:=r;
    x:=a[(l+r) shr 1];
    repeat
      while a[i]<x do inc(i);
      while x<a[j] do dec(j);
      if not(i>j) then
      begin
        swap(a[i],a[j]);
        inc(i);
        dec(j);
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r);
  end;

function find(l,r,x:longint):longint;
  var m:longint;
  begin
    while l<=r do
    begin
      m:=(l+r) shr 1;
      if a[m]=x then exit(m);
      if a[m]>x then r:=m-1 else l:=m+1;
    end;
    exit(-1);
  end;

procedure check(i:longint);
  var j,k,p,x,y:longint;
  begin
    fillchar(v,sizeof(v),false);
    fillchar(b,sizeof(b),0);
    if (a[1]+a[2]-a[i]) mod 2<>0 then exit;
    b[1]:=(a[1]+a[2]-a[i]) div 2;
    b[2]:=a[1]-b[1];
    b[3]:=a[2]-b[1];
    v[1]:=true; v[2]:=true; v[i]:=true;
    p:=3;
    for j:=4 to n do
    begin
      while (p<=m) and v[p] do inc(p);
      if p>m then exit;
      b[j]:=a[p]-b[1];
      v[p]:=true;
      for k:=2 to j-1 do
      begin
        if b[k]>=b[j] then exit;
        x:=find(1,m,b[k]+b[j]);
        if x=-1 then exit;
        y:=x;
        while (y>0) and (a[y]=a[x]) do dec(y);
        inc(y);
        while (y<=m) and (a[y]=a[x]) and v[y] do inc(y);
        if (y>m) or (a[y]<>a[x]) or v[y] then exit;
        v[y]:=true;
      end;
    end;
    inc(t);
    ans[t]:=b;
  end;

begin
  readln(n);
  m:=(n-1)*n div 2;
  for i:=1 to m do
    read(a[i]);
  sort(1,m);
  for i:=3 to n+1 do
    if a[i]<>a[i-1] then check(i);
  writeln(t);
  for i:=1 to t do
  begin
    for j:=1 to n do
      write(ans[i,j],' ');
    writeln;
  end;
end.