Luogu P2292 [HNOI2004]L语言

题目描述

标点符号的出现晚于文字的出现，所以以前的语言都是没有标点的。现在你要处理的就是一段没有标点的文章。

一段文章T是由若干小写字母构成。一个单词W也是由若干小写字母构成。一个字典D是若干个单词的集合。我们称一段文章T在某个字典D下是可以被理解的，是指如果文章T可以被分成若干部分，且每一个部分都是字典D中的单词。

例如字典D中包括单词{‘is’, ‘name’, ‘what’, ‘your’}，则文章‘whatisyourname’是在字典D下可以被理解的，因为它可以分成4个单词：‘what’, ‘is’, ‘your’, ‘name’，且每个单词都属于字典D，而文章‘whatisyouname’在字典D下不能被理解，但可以在字典D’=D+{‘you’}下被理解。这段文章的一个前缀‘whatis’，也可以在字典D下被理解，而且是在字典D下能够被理解的最长的前缀。

给定一个字典D，你的程序需要判断若干段文章在字典D下是否能够被理解。并给出其在字典D下能够被理解的最长前缀的位置。

输入输出格式

输入格式：

输入文件第一行是两个正整数n和m，表示字典D中有n个单词，且有m段文章需要被处理。之后的n行每行描述一个单词，再之后的m行每行描述一段文章。

其中1<=n, m<=20，每个单词长度不超过10，每段文章长度不超过1M。

输出格式：

对于输入的每一段文章，你需要输出这段文章在字典D可以被理解的最长前缀的位置。

输入输出样例

输入样例#1：

4 3 
is
name
what
your
whatisyourname
whatisyouname
whaisyourname

输出样例#1：

14  （整段文章’whatisyourname’都能被理解）
6  （前缀’whatis’能够被理解）
0  （没有任何前缀能够被理解）

Solution

我是用字典树+动态规划的……

大致思路：先将所有单词组个字典树，然后查询时，用个数组c（布尔类型）记录前i个数组成的文章能否被理解。

——————分割不完全的分割线——————

pascal代码如下：

var n,m,i,j,k,l:longint;
a:array[1..1000,'a'..'z']of longint;//字典树
b,c:array[0..1000000]of boolean;//b用来确认是否单词节点，c的意思见上文
s:ansistring;
begin
  readln(n,m);
  k:=1;
  for l:=1 to n do
  begin
    readln(s);
    j:=1;
    for i:=1 to length(s) do
    begin
      if a[j,s[i]]=0 then
      begin
        inc(k);
        a[j,s[i]]:=k;
      end;
      j:=a[j,s[i]];
    end;
    b[j]:=true;
  end;
  //以上为建字典树的步骤
  for l:=1 to m do
  begin
    readln(s);
    fillchar(c,sizeof(c),false);
    c[0]:=true;//先弄个不存在的c[0]以便进行以下步骤
    for i:=0 to length(s) do//先枚举文章的每个节点，看文章的前i位能否加个单词组成新的文章
    if c[i] then//只有当文章的前i位能被理解才能这么做
    begin
      j:=1;
      for k:=1 to 10 do//单词最长才10位，所以每个单词最多只要判断10位就行了（其实是我这名蒟蒻做到这里头都要爆炸了qwq，条件不符合直接无脑break，直接放弃过程中不需判断的最优代码qwq）
      if i+k<=length(s) then//只有当当前判断的那一位不超过文章的位数才能进行下面的步骤啊喂！
      begin
        if a[j,s[i+k]]>0 then
        begin
          j:=a[j,s[i+k]];
          if b[j] then//当那个点正好是单词节点时
          c[i+k]:=true;//前i+k位就可以被理解
        end
        else
        break;
      end
      else
      break;
    end;
    for i:=length(s) downto 0 do//找最长的可以被理解的文章前缀
    if c[i] then
    begin
      writeln(i);
      break;
    end;
  end;
end.

——————分割不完全的分割线——————

终于结束啦！！！

以下是吐槽（请无视）：

这是一道我这名蒟蒻推不出状态转移方程的动态规划，我之前试着用贪心做，结果竟WA了3个点qwq，后来多亏了lcq大神伟大神力的帮助弄到了数据，再看了一下算法标签，一种酸爽油然而生……