ActionScript3.0 对文件的操作（文件的打开保存，查看属性，创建删除目录等）

简要：主要是对File类与FileStream类的使用

创建的是桌面程序。
代码如下：

<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/mx" creationComplete="windowedapplication1_creationCompleteHandler(event)">
    
    <fx:Script>
        <![CDATA[
            
            import mx.core.UIComponent;
            import mx.events.FlexEvent;
            
            public var file2:File;
            public var isOpen:Boolean=false;
            public var fs:FileStream;
            
            protected function windowedapplication1_creationCompleteHandler(event:FlexEvent):void
            {
                //应用程序的相关信息
                out("应用程序目录："+File.applicationDirectory.nativePath);
                out("应用程序存储目录："+File.applicationStorageDirectory.nativePath);
                out("桌面目录："+File.desktopDirectory.nativePath);
                out("文档目录："+File.documentsDirectory.nativePath);
                out("用户目录："+File.userDirectory.nativePath);
            }
            
            public function out(txt:Object):void
            {
                info.appendText(txt.toString()+"\n");
            }
            //文件浏览
            protected function Bws_clickHandler(event:MouseEvent):void
            {
                var file:File=new File();
                var txt:FileFilter=new FileFilter("文档文件","*.txt;*.docx;*.zip");
                var jpg:FileFilter=new FileFilter("图片文件","*.swf; *.gif");
                file.browse([txt,jpg]);
                file.addEventListener(Event.SELECT,onSelect);
                file.addEventListener(Event.CANCEL,onCancel);
            }
            //文件浏览选中事件
            public function onSelect(evt:Event):void
            {
                var file:File=evt.target as File;
                out("选择："+file.nativePath);
            }
            //文件浏览取消事件
            public function onCancel(evt:Event):void
            {
                out("文件选择被取消");
            }
            //打开浏览
            protected function Open_clickHandler(event:MouseEvent):void
            {
                var file:File=new File();
                var txt:FileFilter=new FileFilter("文档文件","*.txt;*.doc");
                var jpg:FileFilter=new FileFilter("图片文件","*.png;*.gif");
                file.browseForOpen("打开文件名",[txt,jpg]);
                file.addEventListener(Event.SELECT,onSelect);
                file.addEventListener(Event.CANCEL,onCancel);
            }
            //保存浏览
            protected function Save_clickHandler(event:MouseEvent):void
            {
                var file:File=File.desktopDirectory;
                file.browseForSave("保存测试文件");
                file.addEventListener(Event.SELECT,onSelect);
                file.addEventListener(Event.CANCEL,onCancel);
            }
            //多文档浏览。一次可以打开多个文件
            protected function MulFiles_clickHandler(event:MouseEvent):void
            {
                var file:File=new File();
                var txt:FileFilter=new FileFilter("文档文件","*.txt;*.doc");
                var jpg:FileFilter=new FileFilter("图片文件","*.png;*.gif");
                file.browseForOpenMultiple("寻找目标",[txt,jpg]);
                file.addEventListener(FileListEvent.SELECT_MULTIPLE,onMulSelect);
                file.addEventListener(Event.CANCEL,onCancel);
            }
            
            public function onMulSelect(evt:FileListEvent):void
            {
                for each (var file:File  in evt.files)
                {
                    out("选择"+file.nativePath);
                }
            }
            
            //目录浏览
            protected function MulCal_clickHandler(event:MouseEvent):void
            {
                var file:File=File.desktopDirectory;
                file.browseForDirectory("寻找目标");
                file.addEventListener(Event.SELECT,onSelect);
                file.addEventListener(Event.CANCEL,onCancel);
            }
            //快速保存文件 , 以下代码 新建了一个setup.txt的文件。然后写入了一段字符串后，保存整个文件。
            protected function FastSave_clickHandler(event:MouseEvent):void
            {
                var file:File=File.applicationStorageDirectory.resolvePath("setup.txt");
                var str:String="this is  save test"+(new Date());
                file.addEventListener(Event.COMPLETE,onComplete);
                file.save(str);
            }
            
            public function onComplete(evt:Event):void
            {
                out("保存完成");
            }
            //快速载入，指定文件所在位置，直接打开，并把信息显示出来
            protected function FastLoad_clickHandler(event:MouseEvent):void
            {
                var file:File=File.applicationStorageDirectory.resolvePath("C:\\Users\\Administrator\\Desktop\\setup.txt");  //文件所在路径，需转义
                file.addEventListener(Event.COMPLETE,dataLoaded);
                out(file.nativePath);
                file.load();
                function dataLoaded(evt:Event):void
                {
                    var str:String;
                    var bytes:ByteArray=file.data;
//                    str=bytes.readUTFBytes(bytes.length);   // 出现中文乱码错误
                    str=bytes.readMultiByte(bytes.length,"cngb");   
                    out(str);
                }
            }
            //浏览文件并查看文件属性
            protected function fileProp_clickHandler(event:MouseEvent):void
            {
                var file:File=new File();
                file.browse();
                file.addEventListener(Event.SELECT,onFileProSelect);
            }
            
            public function onFileProSelect(evt:Event):void
            {
                
                var uic:UIComponent=new UIComponent();  //用来显示文件的图标
                var file:File=evt.target as File;
                out("存在："+file.exists);
                //显示被选择文件图标
                var iconData:Array=file.icon.bitmaps;
                var bmpData:BitmapData=new BitmapData(1,1);
                //复制位图数据
                for(var i:uint=0;i<iconData.length;i++)
                {
                    if(iconData[i].height > bmpData.height)
                    {
                        bmpData=file.icon.bitmaps[i];
                    }
                }
                var iconImg:Bitmap=new Bitmap(bmpData);
                uic.x=800;
                uic.y=100;
                uic.addChild(iconImg);
                addElement(uic);
                
                out("隐藏："+file.isHidden);
                out("目录："+file.isDirectory);
                out("包："+file.isPackage);
                out("快捷方式："+file.isSymbolicLink);
                out("可用空间："+(file.spaceAvailable/1024/1024)+"MB");
                out("上级目录："+file.parent.nativePath);
            }
            //创建文件与目录
            protected function CreateFiles_clickHandler(event:MouseEvent):void
            {
                var newDir:File=File.desktopDirectory.resolvePath("ZZZ");   
                try
                {
                    newDir.createDirectory();    //创建目录, 在桌面上创建了一个ZZZ的文件夹
                    out(newDir.nativePath);
                }
                catch(event:IOError)
                {
                    out("创建目录方式错误");
                }
                
                var newTempDir:File=File.createTempDirectory();  //创建临时目录，在C:\Users\Administrator\AppData\Local\Temp 下 
                out(newTempDir.nativePath);
                
                var newTempFile:File=File.createTempFile();  //创建临时文件   在C:\Users\Administrator\AppData\Local\Temp 下
                out(newTempFile.nativePath);
            }
            //删除目录 （同步方式）
            protected function delete_clickHandler(event:MouseEvent):void
            {
                try
                {
                    var newDir:File=File.desktopDirectory.resolvePath("E:\\ZZZ");   //删除 E:\ZZZ的文件夹
                    newDir.deleteDirectory(true);
                    out("目录已经被删除");
                }
                catch(event:IOError)
                {
                    out("目录删除方式错误.\n"+event);   //如果文件不存在，则报错。 Error: Error #3003: File or directory does not exist.
                }
            }
            //删除目录（异步方式）
            protected function delete2_clickHandler(event:MouseEvent):void
            {
                var newDir:File=File.desktopDirectory.resolvePath("ZZZ"); 
                newDir.addEventListener(Event.COMPLETE,deleComp);
                newDir.addEventListener(IOErrorEvent.IO_ERROR,onIOERR);
                function deleComp(event:Event):void
                {
                    out("目录已被删除!");
                }
                function onIOERR(event:IOErrorEvent):void
                {
                    out("目录删除失败!"+event);
                }
                newDir.moveToTrashAsync();  //删除到回收站
            }
            
            protected function deleteAll_clickHandler(event:MouseEvent):void
            {
                info.text="";
            }
            //异步模式打开文件，并显示读取到的文件
            protected function openAsync_clickHandler(event:MouseEvent):void
            {
                var txt:FileFilter=new FileFilter("文本文件","*.txt;");
                file2=new File();
                file2.addEventListener(Event.SELECT,onFile2Select);
                file2.addEventListener(Event.CANCEL,onCancel);
                file2.browseForOpen("异步模式打开文本文件",[txt]);
            }
            //选中文件并打开
            public function onFile2Select(evt:Event):void
            {
                if(isOpen)
                {
                    fs.close();
                }
                fs=new FileStream();
                fs.addEventListener(Event.COMPLETE,onReadComp);
                fs.addEventListener(IOErrorEvent.IO_ERROR,onError);
                fs.addEventListener(ProgressEvent.PROGRESS,onPrg);
                fs.addEventListener(OutputProgressEvent.OUTPUT_PROGRESS,onOutprg);
                fs.addEventListener(Event.CLOSE,onClose);
                fs.openAsync(file2,FileMode.UPDATE);        //异步更新方式打开文件
                isOpen=true;
                this.title=file2.name;
            }
            //文件打开完成事件
            public function onReadComp(evt:Event):void
            {
                out("文件已经打开并开始读取");
                var str:String=fs.readMultiByte(fs.bytesAvailable,"GBK");
                isOpen=true;
                out(str);
                fs.removeEventListener(Event.COMPLETE,onReadComp);
            }
            
            public function onError(evt:IOErrorEvent):void
            {
                out("文件读写异常");
            }
            //写入进度处理
            public function onOutprg(evt:OutputProgressEvent):void
            {
                out("输出进度："+evt.bytesPending+"/"+evt.bytesTotal);
            }
            //打开进度处理
            public function onPrg(evt:ProgressEvent):void
            {
                out("打开进度："+evt.bytesTotal+"/"+evt.bytesLoaded);
            }
            
            public function onClose(evt:Event):void
            {
                out("关闭");
            }
            
        ]]>
    </fx:Script>
    
    <fx:Declarations>
        <!-- 将非可视元素（例如服务、值对象）放在此处 -->
    </fx:Declarations>
    <s:VGroup gap="20">
        
        <s:Button label="清除" click="deleteAll_clickHandler(event)"/>
        
        <s:TextArea id="info" width="100%" height="100"/>
        <!--多种方式浏览本地文件夹-->
        <s:HGroup  gap="20">
            <s:Button label="浏览" click="Bws_clickHandler(event)"/>
            <s:Button label="浏览（打开）" click="Open_clickHandler(event)"/>
            <s:Button label="浏览（保存）" click="Save_clickHandler(event)"/>
            <s:Button label="浏览（目录）" click="MulCal_clickHandler(event)"/>
            <s:Button label="浏览（多文档）" click="MulFiles_clickHandler(event)"/>
            <s:Button label="异步模式打开文件" click="openAsync_clickHandler(event)"/>
        </s:HGroup>
        
        <s:HGroup gap="20">
            <s:Button label="快速保存" click="FastSave_clickHandler(event)"/>
            <s:Button label="快速载入" click="FastLoad_clickHandler(event)"/>
            <s:Button label="查看文件属性" click="fileProp_clickHandler(event)"/>
        </s:HGroup>
        
        <s:HGroup gap="20">
            <s:Button label="创建文件与目录" click="CreateFiles_clickHandler(event)"/>
            <s:Button label="删除（同步方式）" click="delete_clickHandler(event)"/>
            <s:Button label="删除（异步方式）" click="delete2_clickHandler(event)"/>
        </s:HGroup>
    </s:VGroup>
</s:WindowedApplication>

 @简道云 原创内容，如需转载，请一定署名！否则视为侵权！特此声明！