一个有趣的组合算法

一般的寻找某个集合的子集组合,都是使用递归..找到了一个有趣的算法,实现了连续自然数的子集组合算法...稍微修改一下,就可以实现任意集合的子集组合查找.

组合算法 
  本程序的思路是开一个数组，其下标表示1到m个数，数组元素的值为1表示其下标 
  代表的数被选中，为0则没选中。   
  首先初始化，将数组前n个元素置1，表示第一个组合为前n个数。   
  然后从左到右扫描数组元素值的“10”组合，找到第一个“10”组合后将其变为 
  “01”组合，同时将其左边的所有“1”全部移动到数组的最左端。   
  当第一个“1”移动到数组的m-n的位置，即n个“1”全部移动到最右端时，就得 
  到了最后一个组合。   

例如求5中选3的组合：   
  1   1   1   0   0   //1,2,3   
  1   1   0   1   0   //1,2,4   
  1   0   1   1   0   //1,3,4   
  0   1   1   1   0   //2,3,4   
  1   1   0   0   1   //1,2,5   
  1   0   1   0   1   //1,3,5   
  0   1   1   0   1   //2,3,5   
  1   0   0   1   1   //1,4,5   
  0   1   0   1   1   //2,4,5   
  0   0   1   1   1   //3,4,5 
//=============================我是可爱的分割线========================//

const
  MaxCount = 22;

type
  TMyAry = array[1..MaxCount] of Boolean;

function  SetAryToString(SetAry: TMyAry; const AryLen: Integer): string;
var
  i: Integer;
begin
  Result := '';
  for i := 1 to AryLen do
    if SetAry[i] = True then
      Result := Result + IntToStr(i) + ' ';
end;

function  SetAryNext(var SetAry: TMyAry; const AryLen: Integer): Boolean;
var
  i, j, Cnt: Integer;
begin
  Result := True;
  for i := 1 to AryLen do begin
    if i + 1 > AryLen then
      Break;
    if SetAry[i] and (not SetAry[i + 1]) then begin
      SetAry[i] := False;
      SetAry[i+1] := True;
      Cnt := 0;
      for j := 1 to i do begin
        if SetAry[j] then
          Inc(Cnt);
      end;
      if Cnt < 1 then
        Exit;
      for j := 1 to i do begin
        if j <= Cnt then
          SetAry[j] := True
        else
          SetAry[j] := False;
      end;
      Exit;
    end;
  end;
  Result := False;
end;

function  GetSet(const N, M: Word; StrList: TStrings): Boolean;
var
  SetAry: TMyAry;
  i: Integer;
  TempStr: string;
begin
  Result := False;
  if (N < M) or (M = 0) then
    Exit;
  FillChar(SetAry, N, 0);
  for i := 1 to M do
    SetAry[i] := True;

  try
    StrList.Clear;
    StrList.BeginUpdate;
    StrList.Add(SetAryToString(SetAry, N));
    while SetAryNext(SetAry, N) do begin
      TempStr := SetAryToString(SetAry, N);
      StrList.Add(TempStr);
    end;
  finally
    StrList.EndUpdate;
  end;
end;