0/1背包

program package;
const 
  maxm=200;maxn=30;
var 
  m,n,j,i:integer;
  c,w: array[1..maxn] of integer;
  f:array[0..maxn,0..maxm] of integer;
function max(x,y:integer):integer;            //求x和y的最大值
begin
  if x>y then max:=x else max:=y;
end;

BEGIN
assign(input,'package.in'); 
assign(output,'package.out');
reset(input);
rewrite(output);
  readln(m,n);                            //背包容量m和物品数量n
  for i:= 1 to n do
     readln(w[i],c[i]);                    //每个物品的重量和价值
  for i:=1 to n do
   for j:=1 to m do
    begin                            // f(i，x)表示前i件物品，总重量不超过x的最优价值
      if j>=w[i]  then f[i,j]:=max(f[i-1,j-w[i]]+c[i],f[i-1,j])
                   else f[i,j]:=f[i-1,j];
    end;
  writeln(f[n,m]);                    //f(n,m)为最优解
close(input); 
close(output);
END.

使用二维数组存储各子问题时方便，但当maxm较大时不能定义二维数组f,怎么办,其实可以用一维数组。

program star_package;
var
    i,j,k,n,m:longint;
    f:array[0..100000]of longint;
    w,c:array[0..2000]of longint;
begin
  assign(input,'package.in');
  assign(output,'package.out'); 
  reset(input);
  rewrite(output);
  fillchar(f,sizeof(f),0);
  readln(m,n);                                //背包容量m和物品数量n
  for i:=1 to n do 
     readln(w[i],c[i]);                        //每个物品的重量和价值
  for i:=1 to n do
    for j:=m downto w[i] do                    //这里不能写成for j:=w[i] to m
      if f[j-w[i]]+c[i]>f[j] then f[j]:=f[j-w[i]]+c[i];    // f(j)表示重量不超过j公斤的最大价值
  writeln(f[m]);
  close(input);
  close(ouptut);
end.

      为了输出方案，我们需要在每一步判断取还是不取某件物品时，需要把这个决策信息也记录下来，例如，我们可以修改f[i,j]为记录类型，分别记录数据和决策信息，f[i,j].d记录当前最大价值，f[i,j].s记录当前决策0或1，表示取还是不取该物品。当我们求出目标状态f[n,m]后，我们根据记录的信息从后往前就可以找出一种具体方案，具体实现方法见程序：

参考程序2：输出一种方案

program beibao;  
const
   maxm=200;maxn=30; 
type ar=array[1..maxn] of integer; 
       stat=record           
                 d:integer;          
                 s:integer;
            end; 
var 
   m,n,j,i:integer;  
   c,w:ar; 
   f:array[0..maxn,0..maxm] of stat; 
   s:array[1..maxn] of integer;  
function max(x,y:integer):integer; 
begin 
   if x>y then begin max:=x; f[i,j].s:=1; end 
     else begin max:=y; f[i,j].s:=0; end; 
   end; 
begin 
 assign(input,'beibao.in');  reset(input);   
 readln(m);   
 readln(n); 
 for i:= 1 to n do 
 read(w[i]); 
 for i:= 1 to n do 
 read(c[i]); 
 for i:=1 to m do f[0,i].d:=0; 
 for i:=1 to n do f[i,0].d:=0; 
 for i:=1 to n do 
   for j:=1 to m do
     begin 
         if j>=w[i]  then f[i,j].d:=max(f[i-1,j-w[i]].d+c[i],f[i-1,j].d)
           else  begin f[i,j].d:=f[i-1,j].d; f[i,j].s:=0; end; 
     end;
 j:=m; 
 for i:=n downto 1 do 
   begin 
     s[i]:=f[i,j].s;
     if f[i,j].s=1 then j:=j-w[i]; 
   end;
   writeln; 
  for i:=1 to n do 
   write(s[i]);
  writeln; 
  writeln(f[n,m].d); 
  close(input); 
end. 

经典：背包九讲