PL/SQL编程

declare --声明
  v_sal teacher.sal%type; --创建变量
  v_tname teacher.tname%type;
  v_rank varchar2(10);
  v_sal_rank VARCHAR2(20);
begin
  select t.sal,t.tname
  into v_sal,v_tname  --赋值
  from teacher t 
  where t.tno=1004;
  if v_sal < 2000 then  --IF   start
    v_rank:='临时工';
  elsif v_sal >=2000 and v_sal <15000 then
    v_rank:='蓝领';
  elsif v_sal >=15000 and v_sal <40000 then 
     v_rank:='白领';
  else 
    v_rank:='金领';
  end if;             --IF  end
  CASE v_rank         --CASE START
  WHEN '临时工' THEN
    v_sal_rank:='小于2000';
  WHEN '蓝领' THEN
    v_sal_rank:='[2000,15000)';
  WHEN '白领' THEN
    v_sal_rank:='[15000,40000)';
  ELSE
    v_sal_rank:='大于40000';
  END CASE;            --CASE END
  dbms_output.put_line(v_tname||':'||v_rank||',薪水:'||v_sal_rank);  --输出
end;

-- 游标：是系统给我们用户开设的一个数据缓冲区！存放的是sql语句执行结果！
--每个游标区都有一个名字，用户通过游标一行一行的获取记录!

--01、隐式游标  在我们pl/sql中，程序执行sql语句时，自动创建！就是我们平常的sql语句
--02、显式游标  可以返回多行的查询！
--03、REF游标   用于处理运行时才能确定的动态sql  查询结果

--隐式游标属性
  --01、sql%found  影响了一行或者多行，都返回true
  --02、sql%notfound  没有影响行数，返回true
  --03、sql%rowcount  sql语句影响的行数 
  --04、sql%isopen    游标是否打开，始终为false
declare 
  tname teacher.tname%TYPE;--声明一个变量
  CURSOR teacher_cursor IS SELECT tname FROM teacher; --声明游标
  
begin
  OPEN teacher_cursor;  --打开游标
  FETCH teacher_cursor INTO tname;

  --循环输出tname
  WHILE teacher_cursor%FOUND
    LOOP
      dbms_output.put_line('第'||teacher_cursor%ROWCOUNT||'行，'||'教师的姓名：'||tname);
      FETCH teacher_cursor INTO tname;
    END LOOP;
    CLOSE teacher_cursor;   --关闭游标
  
end;

-- 触发器
   -- :old 代表之前的值
   --:new 代表之后现在的值
   --这两个值   只能在for each  row中使用
   
--update语句 :old    :new
--insert语句 :new
--delete语句 :old

--创建一个teacher_log(只要有人动teacher表，数据就会记录在teacher_log表中)

CREATE TABLE teacher_log(
  logid NUMBER NOT NULL,
  old_value VARCHAR2(200),
  create_date DATE,
  log_type NUMBER,
  tno NUMBER
);
--给logid设置主键
ALTER TABLE teacher_log add CONSTRAINT pk_teacher_logid primary key(logid);

--创建序列
CREATE sequence sq_teacher_logid
minvalue 1
maxvalue 99999999
START WITH 1
increment BY 1
cache 20;

--创建触发器  or replace表示如果存在则修改
CREATE OR REPLACE TRIGGER tr_teacher
AFTER INSERT OR UPDATE OR DELETE  --会在增修删之后出发
ON teacher FOR EACH ROW

--声明pl/sql开始
DECLARE 
v_old_value teacher_log.old_value%TYPE;
v_type teacher_log.log_type%TYPE;
v_tno teacher_log.tno%TYPE;
BEGIN
  IF inserting THEN
    v_type:=1;--新增
    v_tno:=:new.tno;
    v_old_value:=:new.tno||'===='||:new.tname;
   ELSIF deleting THEN
    v_type:=2;--删除
    v_tno:=:old.tno;
    v_old_value:=:old.tno||'===='||:old.tname;
   ELSE
     v_type:=3;--修改
     v_tno:=:old.tno;
     v_old_value:=:old.tno||'===='||:old.tname||'===='||:new.sal;
    END IF;
   
  --将记录写入到teacher_log
  INSERT INTO teacher_log
  VALUES(sq_teacher_logid.nextval,v_old_value,SYSDATE,v_type,v_tno);
  
END tr_teacher;

--函数 function
CREATE OR REPLACE FUNCTION fn_teacher_tid(
  f_tid VARCHAR2
)
RETURN VARCHAR2
IS
f_result teacher.tid%TYPE;

BEGIN
  IF LENGTH(f_tid)!=18 THEN
    dbms_output.put_line('身份证不正确');
  ELSE
    dbms_output.put_line('身份证正确');
  END IF;
  --给返回值赋值
  f_result:=SUBSTR(f_tid,1,6)||'*****'||SUBSTR(f_tid,15);
  RETURN f_result;

END fn_teacher_tid;


--调用函数
SELECT fn_teacher_tid(110101198603304014) FROM dual;

--存储过程   一组完成特定功能的sql语句集
--新增教师   身份证不满足要求，抛出异常

CREATE OR REPLACE PROCEDURE pro_add_teacher
(
p_tno teacher.tno%TYPE,
p_tname teacher.tname%TYPE,
p_tid teacher.tid%TYPE,
p_sal teacher.sal%TYPE
)
IS 
e_tid_validate EXCEPTION;

BEGIN
  IF LENGTH(p_tid)!=18 --判断身份证号不满足18位
    THEN --抛出异常
      RAISE e_tid_validate;
   END IF;
   
INSERT INTO teacher(tno,tname,tid,sal)
VALUES(p_tno,p_tname,p_tid,p_sal);
--提交事务
COMMIT;

--对异常进行处理
EXCEPTION WHEN e_tid_validate THEN
  dbms_output.put_line('请输入正确的身份证号');
  WHEN OTHERS THEN
    dbms_output.put_line('其他异常');
  END pro_add_teacher;



--调用存储过程
CALL pro_add_teacher(2001,'小黑黑','123456789123456789',5000);

 
DECLARE
   v_temp NUMBER:=0;--循环变量
   v_max_deptnum dept_loop.deptno%TYPE;--最大增加值
BEGIN 
  SELECT MAX(deptno) INTO v_max_deptnum FROM dept_loop;
  LOOP   --LOOP START
    v_max_deptnum:=v_max_deptnum+1;--每次循环加1
    INSERT INTO dept_loop
    VALUES(v_max_deptnum,'部门'||v_max_deptnum,'地址'||v_max_deptnum);
    v_temp:=v_temp+1;--每次循环变量加一
    EXIT WHEN v_temp>99;
   END LOOP; --LOOP END
   
   v_temp:=0; --初始化循环变量
   WHILE v_temp<100 LOOP  --WHILE LOOP START
      v_max_deptnum:=v_max_deptnum+1;
       INSERT INTO dept_loop
       VALUES(v_max_deptnum,'部门'||v_max_deptnum,'地址'||v_max_deptnum);
       v_temp:=v_temp+1;
   END LOOP;        --WHILE LOOP END
   
   FOR v_temp IN v_max_deptnum+1..v_max_deptnum+100 LOOP   --FOR LOOP START
     INSERT INTO dept_loop
      VALUES(v_temp,'部门'||v_temp,'地址'||v_temp);
   END LOOP;        --FOR LOOP END
END;