POJ 2749

POJ 2749

题目大意：给出若干个牛棚的坐标，现有两个点d1, d2（交通枢纽点），d1, d2之间有一条路（本题两点的路程为横坐标之差和纵坐标之差的绝对值），求牛棚连到d1，或d2，任意两个牛棚之间最大值的最小值是多少。他还加了一个约束条件，就是给出a对牛棚，每对牛棚是不能连在同一个枢纽点，再给出b对牛棚，每对牛棚一定要连在同一个枢纽点。

解：上网找做法，说这个是一种2sat模型，属于np模型、主要是讨论有节点关系为一定共存和一定不共存这样一些的图。这道题目也是一样（要么不能一起，要么一起）,核心思想是二分答案（和noip2010 no3类似，有时间复习），然后建图讨论是否可行。设x为x处于d1，x+n为x处于d2，然后讨论他们。（建图：定义，如果有a->b说明选择了a则一定要选则b）如果dist[i][1]+dist[j][1]>mid，说明如果点i和点j都连在d1则一定超过，所以对与i连d1时，j一定只能连d2，所以连上一条i->j+n的边，而如果j连d1，那么i必须连d2，所以连边j->i+n，然后根据构图的对称性（这个要看论文仔细钻研）可知选择了一个点，他和他连向的点一定是一个强联通分量，所以tarjan一次，然后找出如果存在col[i]=col[i+n]则说明这幅图不能成立（显然，连d1的同时练d2才成立，显然违反题意了）

注释：好二，因为边的数量又算少了，wa了好多次+浪费了一个多小时。虽然不在乎ac率了，可无谓的错误还是不应该的。

const
        maxn=522 *2;
        bilibili=maxlongint >> 1;
        inf=55555555;
type
        data=record
          dest, next: longint;
        end;
        dota=record
          a, b: longint;
        end;
var
        edge: array[1..maxn * maxn]of data;
        dfn, low, s, vect, col:array[1..maxn]of longint;
        hate, friend: array[1..maxn]of dota;
        dist: array[1..maxn, 1..2]of longint;
        visit: array[1..maxn]of boolean;
        sx1, sx2, sy1, sy2, time, d, color, stot, tot, n, a, b, ans: longint;
procedure add(x, y: longint);
begin
  inc(tot);
  with edge[tot] do begin
    dest := y;
    next := vect[x];
    vect[x] := tot;
  end;
end;

procedure init;
var
        i, j, x, y: longint;
begin
  readln(n, a, b);
  readln(sx1, sy1, sx2, sy2);
  d := abs(sx1-sx2)+abs(sy1-sy2);
  for i := 1 to n do begin
    readln(x, y);
    dist[i][1] := abs(sx1-x) + abs(sy1-y);
    dist[i][2] := abs(sx2-x) + abs(sy2-y);
  end;
  for i := 1 to a do readln(hate[i].a, hate[i].b);
  for i := 1 to b do readln(friend[i].a, friend[i].b);
end;

procedure tarjan(x: longint);
var
        i, u: longint;
begin
  inc(time); inc(stot);
  dfn[x] := time; low[x] := dfn[x];
  s[stot] := x; visit[x] := true;
  i := vect[x];
  while i<>0 do
    with edge[i] do begin
      if dfn[dest]=0 then begin
        tarjan(dest);
        if low[dest]<low[x] then low[x] := low[dest];
      end
        else begin
          if visit[dest] then
            if dfn[dest]<low[x] then low[x] := dfn[dest];
        end;
      i := next;
    end;
  if dfn[x]=low[x] then begin
    inc(color);
    repeat
      u := s[stot];
      visit[u] := false;
      dec(stot);
      col[u] := color;
    until u=x;
  end;
end;

function check(key: longint): boolean;
var
        i, j, x, y: longint;
begin
  tot := 0;
  fillchar(vect, sizeof(vect), 0);
  for i := 1 to n - 1 do
    for j := i+1 to n do begin
      if dist[i][1]+dist[j][1]>key then begin add(i, j+n); add(j, i+n); end;
      if dist[i][2]+dist[j][2]>key then begin add(i+n, j); add(j+n, i); end;
      if dist[i][1]+dist[j][2]+d>key then begin add(i, j); add(j+n, i+n); end;
      if dist[i][2]+dist[j][1]+d>key then begin add(i+n, j+n); add(j, i); end;
    end;
  for i := 1 to a do begin
    x := hate[i].a; y := hate[i].b;
    add(x, y+n); add(x+n, y); add(y, x+n); add(y+n, x);
  end;
  for i := 1 to b do begin
    x := friend[i].a; y := friend[i].b;
    add(x, y); add(x+n, y+n); add(y, x); add(y+n, x+n);
  end;

  color := 0; stot := 0; time := 0;
  fillchar(col, sizeof(col), 0);
  fillchar(dfn, sizeof(dfn), 0);
  fillchar(visit, sizeof(visit), 0);
  for i := 1 to n*2 do
    if col[i]=0 then tarjan(i);

  for i := 1 to n do
    if col[i]=col[i+n] then exit(false);
  exit(true);
end;

procedure main;
var
        st, ed, mid: longint;
begin
  st := 0; ed := inf; ans := -1;
  while st<=ed do begin
    mid := (st+ed) >> 1;
    if check(mid) then begin
      ed := mid -1;
      ans := mid;
    end
      else st := mid + 1;
  end;
end;

procedure print;
begin
  writeln(ans);
end;

begin
  assign(input,'1.txt'); reset(input);
  while not(seekeof) do begin
    init;
    main;
    print;
  end;
end.