洛谷_P1119_灾后重建

题目大意：

地震后，有N个受损的村庄，在任一一个村庄重建完成之前，其他村庄都不能到达这个村庄。

给出N个村庄重建完成的时间和连通的情况。

有Q个询问，问在时间T，A和B这两个村庄是否连通。

若连通，则输出A和B的最短路径，否则输出-1。

题解：

因为保证询问的时间T是不递减，只需判断中转站k是否连通即可。

代码：

var
  n,m,Q:longint;
  t:array [0..2001] of longint;
  a:array [0..201,0..201] of longint;
procedure init;
var
  i,x,y,z:longint;
begin
  fillchar(a,sizeof(a),63);
  fillchar(t,sizeof(t),63);
  readln(n,m);
  for i:=1 to n do
    begin
      read(t[i]);
      a[i,i]:=0;
    end;
  for i:=1 to m do
    begin
      readln(x,y,z);
      x:=x+1; y:=y+1;
      a[x,y]:=z; a[y,x]:=z;
    end;
end;

function min(o,p:longint):longint;
begin
  if o<p then exit(o);
  exit(p);
end;

procedure main;
var
  k,i,j,ii,x,y,tt:longint;
begin
  readln(Q);
  k:=1;
  for ii:=1 to Q do
    begin
      readln(x,y,tt);
      x:=x+1; y:=y+1;
      while t[k]<=tt do
        begin
          for i:=1 to n do
            for j:=1 to n do
              a[i,j]:=min(a[i,j],a[i,k]+a[k,j]);
          inc(k);
        end;
      if (t[x]<=tt) and (t[y]<=tt) and (a[x,y]<>a[0,0]) then
        writeln(a[x,y]) else
        writeln('-1');
    end;
end;

begin
  init;
  main;
end.