bzoj1066 [SCOI2007]蜥蜴

Description

　　在一个r行c列的网格地图中有一些高度不同的石柱，一些石柱上站着一些蜥蜴，你的任务是让尽量多的蜥蜴逃
到边界外。 每行每列中相邻石柱的距离为1，蜥蜴的跳跃距离是d，即蜥蜴可以跳到平面距离不超过d的任何一个石
柱上。石柱都不稳定，每次当蜥蜴跳跃时，所离开的石柱高度减1（如果仍然落在地图内部，则到达的石柱高度不
变），如果该石柱原来高度为1，则蜥蜴离开后消失。以后其他蜥蜴不能落脚。任何时刻不能有两只蜥蜴在同一个
石柱上。

Input

　　输入第一行为三个整数r，c，d，即地图的规模与最大跳跃距离。以下r行为石竹的初始状态，0表示没有石柱
，1~3表示石柱的初始高度。以下r行为蜥蜴位置，“L”表示蜥蜴，“.”表示没有蜥蜴。

Output

　　输出仅一行，包含一个整数，即无法逃离的蜥蜴总数的最小值。

Sample Input

5 8 2
00000000
02000000
00321100
02000000
00000000
........
........
..LLLL..
........
........

 

Sample Output

1

 

HINT

100%的数据满足：1<=r, c<=20, 1<=d<=4

网络流题目，建图的拆1个石柱为2个连上容量为高度的边没有想到。然后做的时候发现无向边得连两条有向边，再加上它们的反向边一共4条，不能用只连2条然后相互作为rev，我也不值得为什么，反正不这样就会WA一个点。

看了别的大神的博客。

传送门：http://www.cnblogs.com/qtyytq/p/5230616.html

program rrr(input,output);
const
  inf=123456789;
type
  etype=record
     t,c,next,rev:longint;
  end;
var
  e:array[0..400040]of etype;
  a,dep,cur:array[-440..440]of longint;
  x,y,z:array[0..440]of longint;
  q:array[0..880]of longint;
  r,c,d,i,j,cnt,tot,h,t,ans,n:longint;
  ma:array[0..22,0..22]of char;
  ch:char;
function min(a,b:longint):longint;
begin
   if a<b then exit(a) else exit(b);
end;
procedure ins(x,y,c:longint);
begin
   inc(cnt);e[cnt].t:=y;e[cnt].c:=c;e[cnt].next:=a[x];a[x]:=cnt;
end;
procedure add(x,y,c:longint);
begin
   ins(x,y,c);e[cnt].rev:=cnt+1;ins(y,x,0);e[cnt].rev:=cnt-1;
end;
procedure bfs;
begin
   for i:=-tot to tot+1 do dep[i]:=-1;
   h:=0;t:=1;q[1]:=0;dep[0]:=0;
   while h<t do
      begin
         inc(h);i:=a[q[h]];
         while i<>0 do
            begin
               if (dep[e[i].t]=-1) and (e[i].c>0) then
                  begin
                     dep[e[i].t]:=dep[q[h]]+1;
                     inc(t);q[t]:=e[i].t;
                  end;
               i:=e[i].next;
            end;
      end;
end;
function dfs(k,f:longint):longint;
var
  i,ans,r:longint;
begin
   if (k=tot+1) or (f=0) then exit(f);
   ans:=0;i:=cur[k];
   while i<>0 do
      begin
         if (dep[e[i].t]=dep[k]+1) and (e[i].c>0) then
            begin
               r:=dfs(e[i].t,min(f,e[i].c));
               dec(e[i].c,r);inc(e[e[i].rev].c,r);
               dec(f,r);inc(ans,r);
               if f=0 then break;
            end;
         i:=e[i].next;cur[k]:=i;
      end;
   if f>0 then dep[k]:=-1;
   exit(ans);
end;
begin
   assign(input,'r.in');assign(output,'r.out');reset(input);rewrite(output);
   readln(r,c,d);
   fillchar(a,sizeof(a),0);cnt:=0;
   tot:=0;
   for i:=1 to r do
      begin
         for j:=1 to c do
            begin
               read(ch);if ch='0' then continue;
               inc(tot);x[tot]:=i;y[tot]:=j;val(ch,z[tot]);
               add(-tot,tot,z[tot]);
            end;
         readln;
      end;
   for i:=1 to r do begin for j:=1 to c do read(ma[i,j]);readln; end;
   n:=0;
   for i:=1 to tot do
      begin
         if ma[x[i],y[i]]='L' then begin add(0,-i,1);inc(n); end;
         if (x[i]<=d) or (y[i]<=d) or (r+1-x[i]<=d) or (c+1-y[i]<=d) then add(i,tot+1,inf);
         for j:=i+1 to tot do
            if sqr(x[i]-x[j])+sqr(y[i]-y[j])<=sqr(d) then
               begin add(i,-j,inf);add(j,-i,inf); end;
      end;
   ans:=0;
   while true do
      begin
         bfs;
         if dep[tot+1]=-1 then break;
         for i:=-tot to tot+1 do cur[i]:=a[i];
         ans:=ans+dfs(0,inf);
      end;
   write(n-ans);
   close(input);close(output);
end.