1509: [NOI2003]逃学的小孩

Description

Input

第一行是两个整数N（3  N  200000）和M，分别表示居住点总数和街道总数。以下M行，每行给出一条街道的信息。第i+1行包含整数Ui、Vi、Ti（1Ui, Vi  N，1  Ti  1000000000），表示街道i连接居住点Ui和Vi，并且经过街道i需花费Ti分钟。街道信息不会重复给出。
Output

仅包含整数T，即最坏情况下Chris的父母需要花费T分钟才能找到Chris。
Sample Input

4 3

1 2 1

2 3 1

3 4 1

Sample Output

4

树dp

其实不是很难，只是要小心细节

我们要找出一个三叉路（允许一条为0）从大到小为a，b，c，使得a+b+b+c最大

所以我们先树dp求出每个点往下走的最长的三条边，但是这条边还可能来自于父亲，所以再dfs一遍，然后更新答案

const
    maxn=200200;
var
    first,u:array[0..maxn]of longint;
    next,last,w:array[0..maxn*2]of longint;
    f:array[0..maxn,0..3]of int64;
    n,m,tot:longint;
    ans:int64;

procedure insert(x,y,z:longint);
begin
    inc(tot);
    last[tot]:=y;
    next[tot]:=first[x];
    first[x]:=tot;
    w[tot]:=z;
end;

procedure up(var x:int64;y:int64);
begin
    if x<y then x:=y;
end;

procedure new(x:longint;y:int64);
begin
    if y>f[x,0] then
      begin
        f[x,2]:=f[x,1];
        f[x,1]:=f[x,0];
        f[x,0]:=y;
      end
    else
      if y>f[x,1] then
        begin
          f[x,2]:=f[x,1];
          f[x,1]:=y;
        end
      else up(f[x,2],y);
end;

procedure dfs(x,fa:longint);
var
    i:longint;
begin
    i:=first[x];
    while i<>0 do
      begin
        if last[i]<>fa then
        begin
          dfs(last[i],x);
          u[last[i]]:=w[i];
          new(x,f[last[i],0]+w[i]);
        end;
        i:=next[i];
      end;
end;

function get(x,y,z:int64):int64;
begin
    exit(x+y*2+z);
end;

procedure dfs2(x,fa:longint);
var
    i:longint;
begin
    if f[x,0]+u[x]=f[fa,0] then new(x,f[fa,1]+u[x])
    else new(x,f[fa,0]+u[x]);
    up(ans,get(f[x,0],f[x,1],f[x,2]));
    i:=first[x];
    while i<>0 do
      begin
        if last[i]<>fa then dfs2(last[i],x);
        i:=next[i];
      end;
end;

procedure main;
var
    i,x,y,z:longint;
begin
    read(n,m);
    for i:=1 to m do
      begin
        read(x,y,z);
        insert(x,y,z);
        insert(y,x,z);
      end;
    dfs(1,0);
    dfs2(1,0);
    write(ans);
end;

begin
    main;
end.