Flash3D学习计划（四）——学习纹理相关知识，载入一张纹理，并应用于前面的矩形；并学习多层纹理映射相关知识，尝试dark map, glow map

实现效果

 

主要代码

package
{
    import com.adobe.utils.AGALMiniAssembler;
    import com.adobe.utils.PerspectiveMatrix3D;
    
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.display.Stage3D;
    import flash.display3D.Context3D;
    import flash.display3D.Context3DProgramType;
    import flash.display3D.Context3DTextureFormat;
    import flash.display3D.Context3DVertexBufferFormat;
    import flash.display3D.IndexBuffer3D;
    import flash.display3D.Program3D;
    import flash.display3D.VertexBuffer3D;
    import flash.display3D.textures.Texture;
    import flash.events.Event;
    import flash.geom.Matrix;
    import flash.geom.Matrix3D;
    import flash.geom.Vector3D;
    
    /**
     * @author smartqi
     * @E-mail: [email=408176274@qq.com]408176274@qq.com[/email]
     * 创建时间：2013-6-29 上午9:36:36
     * 
     */
    public class TextureTest extends Sprite
    {
        
        private var context:Context3D;
        private var vertexBuff:VertexBuffer3D;
        private var indexBuff:IndexBuffer3D;
        private var vertexData:Vector.<Number>;
        private var indexData:Vector.<uint>;
        private var shaderProgram:Program3D;
        private var perspectiveMatrix:PerspectiveMatrix3D;
        private var i:int;
        private var sign:int = 1;
        private const angleGap:Number = 20;
        private var angle:Number = 0;
        private var modelMatrix:Matrix3D;
        private var viewMatrix:Matrix3D;
        private var finalMatrix:Matrix3D;
        private var texture:Texture;
        [Embed (source = "texture.jpg")]
        private var textureClass:Class;
        
        
        public function TextureTest()
        {
            var stage3d:Stage3D = stage.stage3Ds[0];
            stage3d.addEventListener(Event.CONTEXT3D_CREATE,onContextCreate);
            stage3d.requestContext3D();
        }
        
        private function onContextCreate(e:Event):void{
            context = (e.target as Stage3D).context3D;
            if(context == null) return;
            context.enableErrorChecking = true; //允许进行错误检测，release版本应设置
            context.configureBackBuffer(500,500,0); //设置显示区域的大小
            setupVertexBuff(); //设置顶点缓冲
            setupTexture(); //设置纹理缓冲
            setupShaderProgram(); //设置shander
            setupPerspectiveMatrix(); //设置投影矩阵
            initMatrix();
            addEventListener(Event.ENTER_FRAME,onEnterFrame);
        }
        
        private function setupVertexBuff():void{
            vertexData = Vector.<Number>([
                // x    y     z     r     g     b        u    v
                40,        40,        -40,    1,    0,    0, 0, 0,
                40,        -40,    -40,    0,    1,    0, 0, 1,
                -40,    -40,    -40,    0,    0,    1, 1, 1,
                -40,    40,        -40,    1,    1,    1, 1, 0
            ]);
            
            indexData = Vector.<uint>([0,1,2,0,2,3]);
            vertexBuff = context.createVertexBuffer(4,vertexData.length/4);
            vertexBuff.uploadFromVector(vertexData,0,4);
            indexBuff = context.createIndexBuffer(6);
            indexBuff.uploadFromVector(indexData,0,6);
            context.setVertexBufferAt(0,vertexBuff,0,Context3DVertexBufferFormat.FLOAT_3);
            context.setVertexBufferAt(1,vertexBuff,3,Context3DVertexBufferFormat.FLOAT_3);
            context.setVertexBufferAt(2,vertexBuff,6,Context3DVertexBufferFormat.FLOAT_2);
        }
        
        private function setupTexture():void{
            var bitmap:Bitmap = new textureClass();
            texture = context.createTexture(512,512,Context3DTextureFormat.BGRA,true);
            uploadTextureWithMipmaps(texture,bitmap.bitmapData);
            context.setTextureAt(0,texture);
        }
        
        public function uploadTextureWithMipmaps(dest:Texture, src:BitmapData):void
        {
            var ws:int = src.width;
            var hs:int = src.height;
            var level:int = 0;
            var tmp:BitmapData;
            var transform:Matrix = new Matrix();
            tmp = new BitmapData(src.width, src.height, true, 0x00000000);
            while ( ws >= 1 && hs >= 1 )
            { 
                tmp.draw(src, transform, null, null, null, true); 
                dest.uploadFromBitmapData(tmp, level);  //上传不同层次的纹理，满足miplinear映射的需要
                transform.scale(0.5, 0.5);
                level++;
                ws >>= 1;
                hs >>= 1;
                if (hs && ws) 
                {
                    tmp.dispose();
                    tmp = new BitmapData(ws, hs, true, 0x00000000);
                }
            }
            tmp.dispose();
        }
        
        private function setupShaderProgram():void{
            var vertexProgram:AGALMiniAssembler =  new AGALMiniAssembler();
            vertexProgram.assemble(Context3DProgramType.VERTEX,
                "m44 op,va0,vc0
" +
                "mov v1,va1
" +
                "mov v2,va2
");
            var fragmentProgram:AGALMiniAssembler = new AGALMiniAssembler();
            fragmentProgram.assemble(Context3DProgramType.FRAGMENT,
                "tex ft0, v2, fs0 <2d,repeat,miplinear>
" +    
                "mov oc,ft0
");
            shaderProgram = context.createProgram();
            shaderProgram.upload(vertexProgram.agalcode,fragmentProgram.agalcode);
            context.setProgram(shaderProgram);
        }
        
        private function setupPerspectiveMatrix():void{
            perspectiveMatrix = new PerspectiveMatrix3D();
            perspectiveMatrix.perspectiveFieldOfViewRH(Math.PI*90/180,1,1,1000);  //注意这里的角度使用的是弧度
        }
        
        private function initMatrix():void{
            modelMatrix = new Matrix3D();
            viewMatrix = new Matrix3D();
            finalMatrix = new Matrix3D();
        }
        
        private function onEnterFrame(e:Event):void{
            context.clear(0,0,0);
            angle += angleGap;
            modelMatrix.identity();
            modelMatrix.prependRotation(angle,Vector3D.Z_AXIS);  //绕着Z轴旋转物体，注意这里的角度使用的是角度
            if(i>40){
                sign = -1;
            }
            if(i<0){
                sign = 1;
            }
            i += sign;
            viewMatrix.identity();
            viewMatrix.prependTranslation(0,0,-50 + i); //将相机向后移，使物体看起来变小了,将相机向前移，使物体看起来变大
            finalMatrix.identity();
            finalMatrix.append(modelMatrix);
            finalMatrix.append(viewMatrix);
            finalMatrix.append(perspectiveMatrix);
            context.setProgramConstantsFromMatrix(Context3DProgramType.VERTEX,0,finalMatrix,true); //上传最终的顶点转换矩阵，注意这里最后一个参数为true
            context.drawTriangles(indexBuff,0,2);
            context.present();
        }
    }
}

参考：http://www.baidu.com/s?wd=%E5%A4%9A%E5%B1%82%E7%BA%B9%E7%90%86%E6%98%A0%E5%B0%84&pn=40&tn=baiduhome_pg&ie=utf-8&rsv_page=1

Glow Map （发光纹理）

Dark Map(暗纹理)

Decal Map(贴花纹理)

Detail Map(细节纹理)

Gloss Map(高光纹理)

Bump Map(凹凸纹理)

Normal Map(法线纹理)

Parallax Map(四叉纹理)

Shader Map(着色纹理)

http://www.cnblogs.com/arun/articles/1966255.html

参考文献

http://wenku.baidu.com/view/b27454d7360cba1aa811da02.html

http://shiba.hpe.sh.cn/jiaoyanzu/WULI/showArticle.aspx?articleId=376&classId=4

http://blog.csdn.net/huangzhipeng/article/details/7957233