as3与php 上传单个图片demo

只是一个demo，仅跑通上传和存储这一步。

as3的要点：

1、单个上传使用FileReference，一次可选择多张图片可使用FileReferenceList，在flash player 10+可使用load方法可实现预览图片

2、过滤选择文件，使用FileFilter，在调用browse时传入（参数为数组），其中FileFilter实例第二个参数，多个文件使用;分隔，如*.jpg;*.gif

3、监听上载完成可以使用Event.COMPLETE，但若需要获取后台返回的数据流，则需要监听UPLOAD_COMPLETE_DATA(在flash.net.DataEvent包中)

php：

1、接收上传参数，默认为(Filedata)，可在as3中FileReference实例的upload第二个参数指定

2、在windows下上载图片，其中文名称，在保存时需要转成gb2312（不然会出现乱码），在判定图片是否存在是也需要使用gb2312（使用utf-8则不行）

as3的代码（大体思路，不完整版）：

package {

    import flash.display.DisplayObject;
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.ProgressEvent;
    import flash.events.DataEvent;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class UploadImg extends Sprite {

        private var seltBtn:DisplayObject;
        private var _file:FileReference;

        function UploadImg() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;

            init();
        }

        private function init():void {
            seltBtn = getChildByName("selectBtn");

            seltBtn.addEventListener(MouseEvent.CLICK, selectClickHandler);
        }

        private function selectClickHandler(evt:MouseEvent):void {
            var fileRef:FileReference = new FileReference();
            var fileFilter:FileFilter = new FileFilter("图片", "*.jpg;*.gif;*.jpeg;");

            fileRef.addEventListener(Event.SELECT, onSelectHandler);
            fileRef.browse([fileFilter]);

            _file = fileRef
        }

        private function onSelectHandler(evt:Event):void {
            _file.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA, onUploadCompleteHandler);
            _file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            _file.addEventListener(ProgressEvent.PROGRESS, onProgresshandler);
            _file.upload(new URLRequest("http://meteoric.com/Example/upload/test.php"));
        }

        private function onUploadCompleteHandler(evt:DataEvent):void {
            trace('上传完成' + evt.data);
        }

        private function ioErrorHandler(evt:Event):void {
            trace(evt);
        }

        private function onProgresshandler(evt:ProgressEvent):void {
            trace(evt.bytesLoaded/evt.bytesTotal + "----" + evt.bytesLoaded + "--" + evt.bytesTotal);
        }

    }
}

php(需要先开启extension=php_exif.dll，同时要注意post_max_size参数的大小，如果上载的文件过大，可能获取不到FIledata了，需要先判定文件大小)

1、目录结构：

2、不完整示例代码：

<?php
if ($_FILES ["Filedata"] ["error"] > 0) {
    exit("Error: " . $_FILES ["Filedata"]["error"]);
}

echo "<br/>----------存储图片--------<br/>";

$fileName = iconv("utf-8","gb2312", $_FILES ["Filedata"]["name"]);
$reallyName = "upload/".$fileName;

if (file_exists ($reallyName)) {
    echo  $_FILES ["Filedata"]["name"]. " already exists. ";
} else {

    if (!is_dir("upload")) {
        mkdir("upload");
    }

    move_uploaded_file( $_FILES ["Filedata"]["tmp_name"],  $reallyName);
    echo "Stored in: " . "upload/" . $fileName;
}

?>

运行的效果：

上面的代码，仅是思路，写出实现上载功能较为核心的代码。若需要完成更复杂的应用，则要自己在此基础上进行封装一下，例如：多个文件上载，显示上载进度条…