[POJ2774]Long Long Message 解题报告

Long Long Message

　　Description

The little cat is majoring in physics in the capital of Byterland. A piece of sad news comes to him these days: his mother is getting ill. Being worried about spending so much on railway tickets (Byterland is such a big country, and he has to spend 16 shours on train to his hometown), he decided only to send SMS with his mother. 

The little cat lives in an unrich family, so he frequently comes to the mobile service center, to check how much money he has spent on SMS. Yesterday, the computer of service center was broken, and printed two very long messages. The brilliant little cat soon found out: 

1. All characters in messages are lowercase Latin letters, without punctuations and spaces. 
2. All SMS has been appended to each other – (i+1)-th SMS comes directly after the i-th one – that is why those two messages are quite long. 
3. His own SMS has been appended together, but possibly a great many redundancy characters appear leftwards and rightwards due to the broken computer. 
E.g: if his SMS is “motheriloveyou”, either long message printed by that machine, would possibly be one of “hahamotheriloveyou”, “motheriloveyoureally”, “motheriloveyouornot”, “bbbmotheriloveyouaaa”, etc. 
4. For these broken issues, the little cat has printed his original text twice (so there appears two very long messages). Even though the original text remains the same in two printed messages, the redundancy characters on both sides would be possibly different. 

You are given those two very long messages, and you have to output the length of the longest possible original text written by the little cat. 

Background: 
The SMS in Byterland mobile service are charging in dollars-per-byte. That is why the little cat is worrying about how long could the longest original text be. 

Why ask you to write a program? There are four resions: 
1. The little cat is so busy these days with physics lessons; 
2. The little cat wants to keep what he said to his mother seceret; 
3. POJ is such a great Online Judge; 
4. The little cat wants to earn some money from POJ, and try to persuade his mother to see the doctor :( 

 

　　一道卖萌的题面。。>_<

　　给出我们两个字符串，求其最长的连续子串长度

　　用后缀数组解决

　　我将一个字符串接到另一个字符串后面，中间留出足够的空格以免影响答案

　　求出height数组，二分答案

　　然后按照sa数组的顺序验证。　　

　　因为各种各样的错误也调了很久。。

 

program poj2774;
const maxn=400010;
var na,nb,m,n,i:longint;
    s1,s2:ansistring;
    a,height,sa,rank,tmp,s:array[-1..maxn]of longint;

function max(a,b:longint):longint;
begin
    if a>b then exit(a) else exit(b);
end;

function min(a,b:longint):longint;
begin
    if a<b then exit(a) else exit(b);
end;

procedure Suffix_Array;
var i,j,p,size,v0,v1,v00,v01:longint;
begin
    size:=max(200,n);
    for i:=0 to size-1 do s[i]:=0;
    for i:=0 to n-1 do rank[i]:=a[i];
    for i:=0 to n-1 do inc(s[rank[i]]);
    for i:=1 to size-1 do inc(s[i],s[i-1]);
    for i:=n-1 downto 0 do
    begin
        dec(s[rank[i]]);
        sa[s[rank[i]]]:=i;
    end;
    j:=1;
    while j<=n do
    begin
        p:=0;
        for i:=n-j to n-1 do
        begin
            tmp[p]:=i;
            inc(p);
        end;
        for i:=0 to n-1 do if sa[i]-j>=0 then
        begin
            tmp[p]:=sa[i]-j;
            inc(p);
        end;
        for i:=0 to size-1 do s[i]:=0;
        for i:=0 to n-1 do inc(s[rank[i]]);
        for i:=0 to size-1 do inc(s[i],s[i-1]);
        for i:=n-1 downto 0 do
        begin
            dec(s[rank[tmp[i]]]);
            sa[s[rank[tmp[i]]]]:=tmp[i];
        end;
        p:=0;tmp[sa[0]]:=0;
        for i:=1 to n-1 do
        begin
            v0:=sa[i-1];v1:=sa[i];
            if v0+j<n then v00:=rank[v0+j] else v00:=-1;
            if v1+j<n then v01:=rank[v1+j] else v01:=-1;
            if (rank[v0]=rank[v1])and(v00=v01) then tmp[sa[i]]:=p else
            begin
                inc(p);tmp[sa[i]]:=p;
            end;
        end;
        for i:=0 to n-1 do rank[i]:=tmp[i];
        j:=j << 1;
    end;
end;

function compare(i,j,x:longint):longint;
begin
    while (a[i+x-1]=a[j+x-1])and(x<=na)and(x<=nb) do inc(x);
    exit(x-1);
end;

procedure calc_height;
var i:longint;
begin
    if rank[0]=0 then height[0]:=0 else height[0]:=compare(0,sa[rank[0]-1],1);
    for i:=1 to n-1 do
    if rank[i]=0 then height[i]:=0 else height[i]:=compare(i,sa[rank[i]-1],max(height[i-1],1));
end;

function check(x:longint):boolean;
var i,j:longint;
    flag1,flag2:boolean;
begin
    i:=0;
    while i<n do
    begin
        flag1:=false;flag2:=false;
        if sa[i]<=na-x then flag1:=true;
        if (sa[i]>m)and(sa[i]<=n-x) then flag2:=true;
        //控制找到的是真实存在的子串
        j:=i+1;
        while (j<n)and(height[sa[j]]>=x) do
        begin
            if sa[j]<=na-x then flag1:=true;
            if (sa[j]>m)and(sa[j]<=n-x) then flag2:=true;
            inc(j);
        end;
        if flag1 and flag2 then exit(true);
        i:=j;
    end;
    exit(false);
end;

procedure binary;
var L,R,mid,ans:longint;
begin
    ans:=0;
    L:=1;R:=min(na,nb);
    while L<=R do
    begin
        mid:=(L+R) >> 1;
        if check(mid) then
        begin
            ans:=mid;L:=mid+1;
        end else R:=mid-1;
    end;
    writeln(ans);
end;

begin
    readln(s1);
    na:=length(s1);
    for i:=0 to na-1 do a[i]:=ord(s1[i+1])-48;
    m:=1;
    while m<na do m:=m << 1;
    m:=na-1+m;
    readln(s2);
    nb:=length(s2);
    for i:=m+1 to m+1+nb-1 do a[i]:=ord(s2[i-m])-48;
    n:=m+nb+1;
    Suffix_Array;
    calc_height;
    binary;
end.