【BZOJ1305】dance跳舞（最大流，裂点，二分答案）

题意：一次舞会有n个男孩和n个女孩。每首曲子开始时，所有男孩和女孩恰好配成n对跳交谊舞。每个男孩都不会和同一个女孩跳两首（或更多）舞曲。 有一些男孩女孩相互喜欢，而其他相互不喜欢（不会“单向喜欢”）。每个男孩最多只愿意和k个不喜欢的女孩跳舞，而每个女孩也最多只愿意和k个不喜欢的男孩跳舞。 给出每对男孩女孩是否相互喜欢的信息，舞会最多能有几首舞曲？

n<=50,k<=30

思路：明显的最大流问题

将每个男，女都裂成两个点，一个表示喜欢，另一个表示不喜欢

二分答案

(S,num[i,1]) 流量为mid

(num[i,4],T) mid

(num[i,1],num[i,2]) (num[i,3],num[i,4]) k

对于互相喜欢的i,j：

(num[i,1],num[j,4]) 1

不喜欢：

(num[i,2],num[j,3]) 1

 判maxflow是否=mid*n即可

var head,gap,dis:array[0..10000]of longint;
    vet,next,len,fan:array[1..200000]of longint;
    num:array[1..50,1..4]of longint;
    a:array[1..50,1..50]of char;
    n,m,i,l,r,mid,last,s,source,src,tot,k1,j:longint;
    ch:string;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;
 inc(tot);
 next[tot]:=head[b];
 vet[tot]:=a;
 len[tot]:=0;
 head[b]:=tot;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function dfs(u,aug:longint):longint;
var e,v,t,val,flow:longint;
begin
 if u=src then exit(aug);
 e:=head[u]; val:=s-1; flow:=0;
 while e<>0 do
 begin
  v:=vet[e];
  if len[e]>0 then
  begin
   if dis[u]=dis[v]+1 then
   begin
    t:=dfs(v,min(len[e],aug-flow));
    len[e]:=len[e]-t;
    len[fan[e]]:=len[fan[e]]+t;
    flow:=flow+t;
    if dis[source]>=s then exit(flow);
    if aug=flow then break;
   end;
   val:=min(val,dis[v]);
  end;
  e:=next[e];
 end;
 if flow=0 then
 begin
  dec(gap[dis[u]]);
  if gap[dis[u]]=0 then dis[source]:=s;
  dis[u]:=val+1;
  inc(gap[dis[u]]);
 end;
 exit(flow);
end;

function maxflow:longint;
var ans:longint;
begin
 fillchar(gap,sizeof(gap),0);
 fillchar(dis,sizeof(dis),0);
 gap[0]:=s; ans:=0;
 while dis[source]<s do ans:=ans+dfs(source,maxlongint);
 exit(ans);
end;

procedure build;
var i,j:longint;
begin
 fillchar(head,sizeof(head),0);
 tot:=0;
 for i:=1 to n do
 begin
  add(num[i,1],num[i,2],k1);
  add(num[i,3],num[i,4],k1);
 end;
 for i:=1 to n do
 begin
  add(source,num[i,1],mid);
  add(num[i,4],src,mid);
 end;
 for i:=1 to n do
  for j:=1 to n do
   if a[i,j]='Y' then add(num[i,1],num[j,4],1)
    else add(num[i,2],num[j,3],1);
end;

begin
 assign(input,'bzoj1305.in'); reset(input);
 assign(output,'bzoj1305.out'); rewrite(output);
 readln(n,k1);
 for i:=1 to n do
 begin
  readln(ch);
  for j:=1 to n do a[i,j]:=ch[j];
 end;
 for i:=1 to 200000 do
  if i mod 2=1 then fan[i]:=i+1
   else fan[i]:=i-1;
 for i:=1 to n do
  for j:=1 to 4 do
  begin
   inc(s); num[i,j]:=s;
  end;
 source:=s+1; src:=s+2; s:=s+2;
 l:=0; r:=n; last:=0;
 while l<=r do
 begin
  mid:=(l+r)>>1;
  build;
  if maxflow>=mid*n then begin last:=mid; l:=mid+1; end
   else r:=mid-1;
 end;
 writeln(last);
 close(input);
 close(output);
end.