【BZOJ1176】Mokia（CDQ分治）

题意：维护一个W*W的矩阵，初始值均为S.每次操作可以增加某格子的权值,或询问某子矩阵的总权值.

修改操作数M<=160000,询问数Q<=10000,W<=2000000.

思路：CDQ分治

每个操作有t,x,y三维偏序关系

对x排序，对t CDQ分治，对y建立树状数组

树状数组可以用一个时间标记避免每次清空

type arr=record
          x,y,a,b,t,s:longint;
         end;
var p,q:array[0..310000]of arr;
    t:array[0..200000,1..4]of longint;
    ans,a:array[1..210000]of longint;
    sum,tim:array[1..2100000]of longint;
    n1,n,m,i,x,y,z,x1,y1,x2,y2,time:longint;

procedure swap(var x,y:arr);
var t:arr;
begin
 t:=x; x:=y; y:=t;
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=q[(l+r)>>1].x;
 repeat
  while mid>q[i].x do inc(i);
  while mid<q[j].x do dec(j);
  if i<=j then
  begin
   swap(q[i],q[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

procedure qsort1(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=q[(l+r)>>1].t;
 repeat
  while mid>q[i].t do inc(i);
  while mid<q[j].t do dec(j);
  if i<=j then
  begin
   swap(q[i],q[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort1(l,j);
 if i<r then qsort1(i,r);
end;

function lowbit(x:longint):longint;
begin
 exit(x and (-x));
end;

procedure update(x,y:longint);
begin
 while x<=m do
 begin
  if tim[x]<>time then sum[x]:=0;
  tim[x]:=time;
  sum[x]:=sum[x]+y;
  x:=x+lowbit(x);
 end;
end;

function query(x:longint):longint;
begin
 query:=0;
 while x>0 do
 begin
  if tim[x]=time then query:=query+sum[x];
  x:=x-lowbit(x);
 end;
end;


procedure cdq(l,r:longint);
var mid,i,j,l1,r1:longint;
begin
 if l=r then exit;
 mid:=(l+r)>>1;
 l1:=l; r1:=mid+1;
 for i:=l to r do
  if q[i].t<=mid then
  begin
   p[l1]:=q[i]; inc(l1);
  end
   else
   begin
    p[r1]:=q[i]; inc(r1);
   end;
 for i:=l to r do q[i]:=p[i];
 cdq(l,mid);
 j:=l; inc(time);
 for i:=mid+1 to r do
 begin
  while (j<=mid)and(q[j].x<=q[i].x) do
  begin
   if q[j].b=0 then update(q[j].y,q[j].a);
   inc(j);
  end;
  if q[i].b=1 then q[i].s:=q[i].s+query(q[i].y);
 end;
 cdq(mid+1,r);
 l1:=l; r1:=mid+1;
 for i:=l to r do
  if ((q[l1].x<q[r1].x)and(l1<=mid))or(r1>r) then
  begin
   p[i]:=q[l1]; inc(l1);
  end
   else
   begin
    p[i]:=q[r1]; inc(r1);
   end;
 for i:=l to r do q[i]:=p[i];

end;

begin
 assign(input,'bzoj1176.in'); reset(input);
 assign(output,'bzoj1176.out'); rewrite(output);
 read(n1); read(m); inc(m);
 while not eof do
 begin
  read(x);
  if x=3 then break;
  inc(n1);
  case x of
   1:
   begin
    inc(n);
    read(q[n].x,q[n].y,q[n].a);
    inc(q[n].x); inc(q[n].y);
    q[n].b:=0;
    q[n].t:=n;
   end;
   2:
   begin
    read(x1,y1,x2,y2);
    inc(n); q[n].x:=x1; q[n].y:=y1; q[n].b:=1; q[n].t:=n; t[n1,1]:=n;
    inc(n); q[n].x:=x1; q[n].y:=y2+1; q[n].b:=1; q[n].t:=n; t[n1,2]:=n;
    inc(n); q[n].x:=x2+1; q[n].y:=y1; q[n].b:=1; q[n].t:=n; t[n1,3]:=n;
    inc(n); q[n].x:=x2+1; q[n].y:=y2+1; q[n].b:=1; q[n].t:=n; t[n1,4]:=n;
   end;
  end;
 end;
 qsort(1,n);
 cdq(1,n);
 qsort1(1,n);
 for i:=1 to n1 do ans[i]:=q[t[i,1]].s+q[t[i,4]].s-q[t[i,2]].s-q[t[i,3]].s;
 for i:=1 to n1 do
  if t[i,1]>0 then writeln(ans[i]);
 close(input);
 close(output);
end.