【51NOD1806】wangyurzee的树（Prufer编码，容斥原理，组合计数）

题意：有n个点和m条限制，每条限制限制了一个点的度数不能为某个数。

求合法的树的个数模10^9+7

n<=10^6

m<=17

思路：WYZ作业

首先m<=17显然是2^m容斥

枚举每一个限制有用或没用，考虑某一个约束情况下的方案数

Caylay定理：n个点的生成树的个数=n^(n-2)

Prufer序列：一个长度为n-2的Prufer序列对应唯一的一棵n个节点的树，度数为a[i]的点在其中出现了(a[i]-1)次

考虑先在序列中填上所有的受约束条件的点，它们的方案数是C(n-2,a[1]-1)*C(n-2-(a[1]-1),a[2]-1)*……

化简得：

(n-2)!/((a[1]-1)!(a[2]-1)!……*(n-2-sigma(a[i]-1))!)

考虑没有约束的点可以随意在剩下的序列中出现，它们的方案数为：

(n-p)^(n-2-sigma(a[i]-1))

其中p为选中的约束条件个数

将两部分相乘，根据p的奇偶性进行容斥计算即可

几个hack点：

1.对于同一个点可能会有多个约束条件，需要判断某一个点是否被多次限制，如果被多次限制就不能计入答案

2.n=1需要特判ans=1（真的吗，这个点可是坑了我5点头盾）

const mo=1000000007;
var flag:array[1..1000000]of longint;
    fac,exf:array[0..1000000]of int64;
    a,b,c:array[1..17]of longint;
    n,m,i:longint;
    sun:int64;

function mult(x,y:longint):int64;
var tmp:int64;
begin
 tmp:=x; mult:=1;
 while y>0 do
 begin
  if y and 1=1 then mult:=mult*tmp mod mo;
  tmp:=tmp*tmp mod mo;
  y:=y>>1;
 end;
end;

procedure dfs(k:longint);
var i,j,tot,sum:longint;
    ans:int64;
begin
 if k=m+1 then
 begin
  tot:=0; ans:=fac[n-2]; sum:=n-2;
  for i:=1 to m do
   if c[i]>0 then
   begin
    inc(tot);
    inc(flag[a[i]]);
    sum:=sum-(b[i]-1);
   end;
  for i:=1 to m do
   if (c[i]>0)and(flag[a[i]]>1) then
   begin
    for j:=1 to m do
     if c[j]>0 then dec(flag[a[j]]);
    exit;
   end;
  for i:=1 to m do
   if c[i]>0 then ans:=ans*exf[b[i]-1] mod mo;
  //writeln(sum);
  if sum>=0 then
  begin
   ans:=ans*exf[sum] mod mo;
   ans:=ans*mult(n-tot,sum) mod mo;
   if tot and 1=0 then sun:=(sun+ans) mod mo
    else sun:=(sun-ans) mod mo;
   sun:=(sun+mo) mod mo;
  end;
  for i:=1 to m do
   if c[i]>0 then dec(flag[a[i]]);
  exit;
 end;
 if b[k]=0 then dfs(k+1)
  else
  begin
   c[k]:=1;
   dfs(k+1);
   c[k]:=0;
   dfs(k+1);
  end;
end;

begin
 assign(input,'51nod1806.in'); reset(input);
 assign(output,'51nod1806.out'); rewrite(output);
 readln(n,m);
 if n=1 then
 begin
  writeln(1);
  exit;
 end;
 for i:=1 to m do read(a[i],b[i]);
 exf[0]:=1; exf[1]:=1; fac[0]:=1;
 for i:=1 to 1000000 do fac[i]:=fac[i-1]*i mod mo;
 for i:=2 to 1000000 do exf[i]:=exf[mo mod i]*(mo-mo div i) mod mo;
 for i:=1 to 1000000 do exf[i]:=exf[i-1]*exf[i] mod mo;
 dfs(1);
 writeln(sun);
 close(input);
 close(output);
end.