bzoj1412

比较裸的最小割

注意狼和羊的领地可以通过空地相连

const inf=100000007;
      dx:array[1..4] of integer=(0,0,1,-1);
      dy:array[1..4] of integer=(-1,1,0,0);

type node=record
       next,point,flow:longint;
     end;

var edge:array[0..200010] of node;
    a,num:array[0..110,0..110] of longint;
    p,cur,h,numh,pre:array[0..10010] of longint;
    n,m,x,y,len,i,j,t,k:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y,f:longint);
  begin
    inc(len);
    edge[len].point:=y;
    edge[len].flow:=f;
    edge[len].next:=p[x];
    p[x]:=len;
  end;

function sap:longint;
  var s,u,i,j,neck,q,tmp:longint;
  begin
    u:=0;
    numh[0]:=t+1;
    sap:=0;
    while h[0]<t+1 do
    begin
      if u=t then
      begin
        i:=0;
        neck:=inf;
        while i<>t do
        begin
          j:=cur[i];
          if neck>edge[j].flow then
          begin
            neck:=edge[j].flow;
            s:=i;
          end;
          i:=edge[j].point;
        end;
        i:=0;
        while i<>t do
        begin
          j:=cur[i];
          dec(edge[j].flow,neck);
          inc(edge[j xor 1].flow,neck);
          i:=edge[j].point;
        end;
        u:=s;
        sap:=sap+neck;
      end;
      q:=-1;
      i:=p[u];
      while i<>-1 do
      begin
        j:=edge[i].point;
        if (edge[i].flow>0) and (h[u]=h[j]+1) then
        begin
          q:=i;
          break;
        end;
        i:=edge[i].next;
      end;
      if q<>-1 then
      begin
        cur[u]:=q;
        pre[j]:=u;
        u:=j;
      end
      else begin
        dec(numh[h[u]]);
        if numh[h[u]]=0 then exit;
        tmp:=t+1;
        i:=p[u];
        while i<>-1 do
        begin
          j:=edge[i].point;
          if edge[i].flow>0 then tmp:=min(tmp,h[j]);
          i:=edge[i].next;
        end;
        h[u]:=tmp+1;
        inc(numh[h[u]]);
        if u<>0 then u:=pre[u];
      end;
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n,m);
  for i:=1 to n do
    for j:=1 to m do
    begin
      read(a[i,j]);
      inc(t);
      num[i,j]:=t;
    end;
  inc(t);
  for i:=1 to n do
    for j:=1 to m do
    begin
      if a[i,j]=1 then
      begin
        add(0,num[i,j],inf);
        add(num[i,j],0,0);
      end
      else if a[i,j]=2 then
      begin
        add(num[i,j],t,inf);
        add(t,num[i,j],0);
      end;
      for k:=1 to 4 do
      begin
        x:=i+dx[k];
        y:=j+dy[k];
        if (x>0) and (x<=n) and (y>0) and (y<=m) then
        begin
          if (a[i,j]=1) and (a[x,y]<>1) then
          begin
            add(num[i,j],num[x,y],1);
            add(num[x,y],num[i,j],0);
          end
          else if (a[i,j]=0) then
          begin
            add(num[i,j],num[x,y],1);
            add(num[x,y],num[i,j],0);
          end;
        end;
      end;
    end;
  writeln(sap);
end.