poj1064 cable master（最大值问题：二分+贪心）

题意：

有n条电缆，他们的长度分别为l[i]。如果从n条电缆中切割出K条长度相同的电缆的话，这k条电缆每条最长能多长？答案小数点后保留两位有效数字。

输入：

n， k

n行：l[i]

Sample Input

4 11

8.02

7.43

4.57

5.39

Sample Output

2.00

数据范围：

1<=N<=10000;

1<=k<=10000;

1<=l[i]<=100000。

分析：

设命题：can(x)=能切割出k条长度为x的电缆。

问题转化:求can(x)成立的最大的x。

提示：为了避免实数运算误差，把电缆长度放大100倍，化为整数，最后不要忘了把结果再除以100即可。

const
  maxn=10000;
var
  a:array[1..maxn] of longint;
  n,k:longint;
  procedure init;
    var i:longint; x:real;
    begin
      assign(input,'poj1064.in'); reset(input);
      readln(n,k);
      for i:=1 to n do
        begin
          readln(x);
          a[i]:=trunc(x*100);
        end;
      close(input);
    end;
  function can(x:longint):boolean;
    var s,i:longint;
    begin
      s:=0;
      for i:=1 to n do
        s:=s+a[i] div x;
      exit(s>=k);
    end;
  function find:longint;
    var l,r,mid:longint;
    begin
      l:=0; r:=10000000;
      while l<r do
        begin
          mid:=(l+r+1) div 2;
          if can(mid) then l:=mid   //还可能再加长
          else r:=mid-1; // 过长无法切割k份，需缩短
        end;
      exit(l);
    end;
begin
  init;
  writeln(find/100.0:0:2);
end.