Android实例-Delphi在运行时更改Android屏幕旋转(IOS也支持，不过我可没有苹果机，测试不了)

相关资料：

https://www.it1352.com/624177.html

PS:

如果手机锁定方向时，只能是竖向、横向、倒转横向。如果方向未锁定时，可以是竖向、横向、倒转竖向、倒转横向。

android实例：

unit Unit2;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMXTee.Engine,
  FMXTee.Procs, FMXTee.Chart, FMX.Layouts, FMX.Controls.Presentation,
  FMX.StdCtrls;

type
  TForm2 = class(TForm)
    Layout1: TLayout;
    Chart1: TChart;
    Layout2: TLayout;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form2: TForm2;

implementation
uses
  FMX.Platform; //需要引入
{$R *.fmx}
{$R *.LgXhdpiPh.fmx ANDROID}

procedure APPSetScreenOrientation(ADirection: TScreenOrientation);
var
  ScreenService: IFMXScreenService;
  OrientSet: TScreenOrientations;
begin
  if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService))
  then
  begin
    //Portrait 竖向,纵向
    //Landscape 横向
    //InvertedPortrait 倒转竖向,纵向
    //InvertedLandscape 倒转横向
    OrientSet := [ADirection];
    ScreenService.SetScreenOrientation(OrientSet);
  end;
end;

procedure TForm2.Button1Click(Sender: TObject);
begin
  APPSetScreenOrientation(TScreenOrientation.Portrait);
end;

procedure TForm2.Button2Click(Sender: TObject);
begin
  APPSetScreenOrientation(TScreenOrientation.Landscape);
end;

procedure TForm2.Button3Click(Sender: TObject);
begin
  APPSetScreenOrientation(TScreenOrientation.InvertedPortrait);
end;

procedure TForm2.Button4Click(Sender: TObject);
begin
  APPSetScreenOrientation(TScreenOrientation.InvertedLandscape);
end;

procedure TForm2.Button5Click(Sender: TObject);
var
  ScreenService: IFMXScreenService;
begin
  if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService))
  then
  begin
    case ScreenService.GetScreenOrientation of
      TScreenOrientation.Portrait: ShowMessage('Portrait');
      TScreenOrientation.Landscape: ShowMessage('landscape');
      TScreenOrientation.InvertedPortrait: ShowMessage('Inverted-Portrait');
      TScreenOrientation.InvertedLandscape: ShowMessage('Inverted-Landscape');
      else ShowMessage('not set');
    end;
  end;
end;

end.

 IOS实例（我没有苹果机，没测试过）：

Uses: iOSapi.UIKit; 

procedure ChangeiOSorientation(toOrientation: UIInterfaceOrientation;
possibleOrientations: TScreenOrientations);
var
    win : UIWindow;
    App : UIApplication;
    viewController : UIViewController;
    oucon: UIViewController;
begin
    Application.FormFactor.Orientations := []; //Change supported orientations
    App := TUIApplication.Wrap(TUIApplication.OCClass.sharedApplication);
    win := TUIWindow.Wrap(App.windows.objectAtIndex(0)); //The first Windows is always the main Window

    App.setStatusBarOrientation(toOrientation);
    {After you have changed your statusbar orientation set the
    Supported orientation/orientations to whatever you need}
    Application.FormFactor.Orientations := possibleOrientations;
    viewController := TUIViewController.Wrap(TUIViewController.alloc.init);//dummy ViewController
    oucon := TUIViewController.Wrap(TUIViewController.alloc.init);
    {Now we are creating a new Viewcontroller now when it is created
     it will have to check what is the supported orientations}
    oucon := win.rootViewController;//we store all our current content to the new ViewController
    Win.setRootViewController(viewController);
    Win.makeKeyAndVisible;// We display the Dummy viewcontroller

    win.setRootViewController(oucon);
    win.makeKeyAndVisible; 
    {And now we Display our original Content in a new Viewcontroller 
     with our new Supported orientations} 
end;

调用：

 ChangeiOSorientation(UIInterfaceOrientationPortrait,[TScreenOrientation.Portrait,TScreenOrientation.Landscape,TScreenOrientation.InvertedLandscape]);