bzoj2878

又是环套树dp，这次不是我擅长的类型

首先考虑树上的暴力，肯定是穷举起点然后以起点为根dp

我们用g[i]表示以点i为期望走的路径总长，答案就是1/n*Σ(g[i]/d[i]) （d[i]表示点度数）

不难发现我们只需要两次dfs就能求出g[i]，即先求出向下的，然后求向上的

具体的，我们设f[x]表示x向孩子走期望路径长度，这个一次dfs就可以求出来，这时候g[x]求出来的是向孩子走期望路径的总长

再做一次dfs，要加上向上走的路径，可以得到g[y]=g[y]+(g[x]-f[y]-w(x,y))/(d[x]-1)+w(x,y) [fa[y]=x] 注意度数为1的点

那么树就搞定了，环怎么做呢？

还是按照基本思路，把环放到根上，求出环上每个点向下的g[x]

注意到题目给出的条件，环上的点很少，因此我们可以暴力依次计算每个点的g[x]

还是类似上面的思路，并不难，注意细节即可

type node=record
       po,next,num:longint;
     end;

var w,u,f,g:array[0..100010] of double;
    cir,v:array[0..100010] of boolean;
    fp,fa,d,p,b,q,c:array[0..100010] of longint;
    e:array[0..200010] of node;
    j,i,n,m,len,x,y,z,s,t:longint;
    ans:double;

procedure add(x,y,z:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    e[len].num:=z;
    p[x]:=len;
    inc(d[x]);
  end;

procedure dfs1(x:longint);
  var i,y:longint;
  begin
    v[x]:=true;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if not v[y] and not cir[y] then
      begin
        dfs1(y);
        g[x]:=g[x]+f[y]+e[i].num;
      end;
      i:=e[i].next;
    end;
    if d[x]>1 then f[x]:=g[x]/(d[x]-1);
  end;

procedure dfs2(x:longint);
  var i,y,k:longint;
  begin
    v[x]:=true;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if not v[y] and not cir[y] then
      begin
        k:=d[x]-1;
        if k=0 then k:=1;
        g[y]:=g[y]+(g[x]-f[y]-e[i].num)/k+e[i].num;
        dfs2(y);
      end;
      i:=e[i].next;
    end;
  end;

procedure find(x:longint);
  var i,y,z:longint;
  begin
    inc(t);
    b[x]:=t;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if b[y]=0 then
      begin
        fa[y]:=x;
        fp[y]:=e[i].num;
        find(y);
      end
      else if (y<>fa[x]) and (b[y]<b[x]) then
      begin
        cir[y]:=true;
        z:=x;
        inc(s); q[1]:=y;
        c[1]:=e[i].num;
        while z<>y do
        begin
          inc(s);
          q[s]:=z;
          c[s]:=fp[z];
          cir[z]:=true;
          z:=fa[z];
        end;
      end;
      i:=e[i].next;
    end;
  end;

begin
  readln(n,m);
  for i:=1 to m do
  begin
    readln(x,y,z);
    add(x,y,z);
    add(y,x,z);
  end;
  if m=n-1 then
  begin
    dfs1(1);
    fillchar(v,sizeof(v),false);
    dfs2(1);
  end
  else begin
    find(1);
    fillchar(v,sizeof(v),false);
    for i:=1 to s do
    begin
      x:=q[i];
      d[x]:=d[x]-2;
      dfs1(x);
      q[i+s]:=q[i];
      c[i+s]:=c[i];
    end;
    for i:=1 to s do
    begin
      for j:=i+s-1 downto i do
      begin
        x:=q[j];
        if j=i+s-1 then
        begin
          z:=d[x];
          if z=0 then inc(z);
          u[x]:=g[x]/z;
        end
        else begin
          u[x]:=u[q[j+1]]+c[j];
          if j<>i then
            u[x]:=(u[x]+g[x])/(d[x]+1);
        end;
      end;
      for j:=i+1 to i+s do
      begin
        x:=q[j];
        if j<>i+s then u[x]:=0;
        if j=i+1 then
        begin
          z:=d[x];
          if z=0 then inc(z);
          u[x]:=g[x]/z;
        end
        else begin
          u[x]:=u[x]+u[q[j-1]]+c[j-1];
          if j<>i+s then
            u[x]:=(u[x]+g[x])/(d[x]+1);
        end;
      end;
      w[q[i]]:=u[q[i]];
    end;
    fillchar(v,sizeof(v),false);
    for i:=1 to s do
    begin
      x:=q[i];
      g[x]:=g[x]+w[x];
      d[x]:=d[x]+2;
    end;
    for i:=1 to s do
      dfs2(q[i]);
  end;
  for i:=1 to n do
    ans:=ans+g[i]/d[i];
  writeln(ans/n:0:5);
end.