POJ 3321 Apple Tree 线段树

题意/Description：

    There is an apple tree outside of kaka's house. Every autumn, a lot of apples will grow in the tree. Kaka likes apple very much, so he has been carefully nurturing the big apple tree.

    The tree has N forks which are connected by branches. Kaka numbers the forks by 1 to N and the root is always numbered by 1. Apples will grow on the forks and two apple won't grow on the same fork. kaka wants to know how many apples are there in a sub-tree, for his study of the produce ability of the apple tree.

    The trouble is that a new apple may grow on an empty fork some time and kaka may pick an apple from the tree for his dessert. Can you help kaka?

                                                     

读入/Input：

    The first line contains an integer N (N ≤ 100,000) , which is the number of the forks in the tree.
    The following N - 1 lines each contain two integers u and v, which means fork u and fork v are connected by a branch.
    The next line contains an integer M (M ≤ 100,000).
    The following M lines each contain a message which is either
    "C x" which means the existence of the apple on fork x has been changed. i.e. if there is an apple on the fork, then Kaka pick it; otherwise a new apple has grown on the empty fork.
or
    "Q x" which means an inquiry for the number of apples in the sub-tree above the fork x, including the apple (if exists) on the fork x
    Note the tree is full of apples at the beginning

 

输出/Output：

    For every inquiry, output the correspond answer per line.

 

题解/solution：

  用线段树，每次询问一个区间的苹果数目，修改的是一个点的值。只要每科子树的节点编号是连续的就可以用线段树做了。这个很容易做到，按dfs建树的顺序给节点编号，那么每棵子树的编号就都是连续的了。建树的时候顺便求出每个节点的儿子个数，那么查询的时候其区间就是(num[t],num[t]+son[t]-1)。

  我做起来总是WA，好烦。经过不懈努力，用了210分钟，把上帝感动了，于是AC。庆祝一下，。

 

代码/Code：

type
  arr=record
    l,r,sum:longint;
  end;
type
  earr=record
    x,w:longint;
  end;
var
  e:array [0..440001] of earr;
  tree:array [0..440001] of arr;
  a,ls,text,son,num:array [0..110001] of longint;
  n,m,len,nm:longint;
procedure ins(x,y:longint);
var
  m:longint;
begin
  inc(len);
  e[len].x:=y;
  e[len].w:=ls[x];
  ls[x]:=len;
end;

procedure dfs(t:longint);
var
  k,u:longint;
begin
  inc(nm);
  num[t]:=num[t]+nm;
  son[t]:=1; k:=ls[t];
  while k<>-1 do
    begin
      u:=e[k].x;
      if text[u]=0 then
        begin
          text[u]:=1;
          dfs(u);
          text[u]:=0;
          son[t]:=son[t]+son[u];
        end;
      k:=e[k].w;
    end;
end;

procedure cre(p,b,e:longint);
var
  m:longint;
begin
  with tree[p] do
    begin
      l:=b; r:=e; sum:=1;
      if b=e then exit;
      m:=(l+r) div 2;
      cre(p*2,b,m);
      cre(p*2+1,m+1,e);
      sum:=tree[p*2].sum+tree[p*2+1].sum;
    end;
end;

procedure instree(p,b,e:longint);
var
  m:longint;
begin
  with tree[p] do
    begin
      if (l=e) and (r=e) then
        begin
          sum:=sum+b;
          exit;
        end;
      m:=(l+r) div 2;
      if e<=m then instree(p*2,b,e) else
        if m+1<=e then instree(p*2+1,b,e);
      sum:=sum+b;
    end;
end;

function count(p,b,e:longint):longint;
var
  m,ans:longint;
begin
  with tree[p] do
    begin
      if (l>=b) and (r<=e) then exit(sum);
      m:=(l+r) div 2; ans:=0;
      if b<=m then ans:=ans+count(p*2,b,e);
      if e>=m+1 then ans:=ans+count(p*2+1,b,e);
      count:=ans;
    end;
end;

procedure main;
var
  o,p,i:longint;
  ch:char;
begin
  fillchar(e,sizeof(e),0);
  readln(n);
  len:=0;
  fillchar(ls,sizeof(ls),255);
  for i:=1 to n-1 do
    begin
      readln(o,p);
      ins(o,p);
      ins(p,o);
    end;
  fillchar(text,sizeof(text),0);
  fillchar(son,sizeof(son),0);
  text[1]:=1; nm:=0;
  dfs(1);
  cre(1,1,n);
  readln(m);
  for i:=1 to m do
    begin
      readln(ch,o);
      if ch='Q' then writeln(count(1,num[o],num[o]+son[o]-1)) else
        begin
          a[o]:=a[o] xor 1;
          if a[o]=1 then instree(1,-1,num[o])
                    else instree(1,1,num[o]);
        end;
    end;
end;

begin
  main;
end.